52a93cdd04bc9a6a5bae35a12b00476befcbfbd6
[muen/linux.git] / arch / powerpc / kernel / vmlinux.lds.S
1 /* SPDX-License-Identifier: GPL-2.0 */
2 #ifdef CONFIG_PPC64
3 #define PROVIDE32(x)    PROVIDE(__unused__##x)
4 #else
5 #define PROVIDE32(x)    PROVIDE(x)
6 #endif
7 #include <asm/page.h>
8 #include <asm-generic/vmlinux.lds.h>
9 #include <asm/cache.h>
10 #include <asm/thread_info.h>
11
12 #if defined(CONFIG_STRICT_KERNEL_RWX) && !defined(CONFIG_PPC32)
13 #define STRICT_ALIGN_SIZE       (1 << 24)
14 #else
15 #define STRICT_ALIGN_SIZE       PAGE_SIZE
16 #endif
17
18 ENTRY(_stext)
19
20 PHDRS {
21         kernel PT_LOAD FLAGS(7); /* RWX */
22         notes PT_NOTE FLAGS(0);
23         dummy PT_NOTE FLAGS(0);
24
25         /* binutils < 2.18 has a bug that makes it misbehave when taking an
26            ELF file with all segments at load address 0 as input.  This
27            happens when running "strip" on vmlinux, because of the AT() magic
28            in this linker script.  People using GCC >= 4.2 won't run into
29            this problem, because the "build-id" support will put some data
30            into the "notes" segment (at a non-zero load address).
31
32            To work around this, we force some data into both the "dummy"
33            segment and the kernel segment, so the dummy segment will get a
34            non-zero load address.  It's not enough to always create the
35            "notes" segment, since if nothing gets assigned to it, its load
36            address will be zero.  */
37 }
38
39 #ifdef CONFIG_PPC64
40 OUTPUT_ARCH(powerpc:common64)
41 jiffies = jiffies_64;
42 #else
43 OUTPUT_ARCH(powerpc:common)
44 jiffies = jiffies_64 + 4;
45 #endif
46 SECTIONS
47 {
48         . = KERNELBASE;
49
50 /*
51  * Text, read only data and other permanent read-only sections
52  */
53
54         _text = .;
55         _stext = .;
56
57         /*
58          * Head text.
59          * This needs to be in its own output section to avoid ld placing
60          * branch trampoline stubs randomly throughout the fixed sections,
61          * which it will do (even if the branch comes from another section)
62          * in order to optimize stub generation.
63          */
64         .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) {
65 #ifdef CONFIG_PPC64
66                 KEEP(*(.head.text.first_256B));
67 #ifdef CONFIG_PPC_BOOK3E
68 #else
69                 KEEP(*(.head.text.real_vectors));
70                 *(.head.text.real_trampolines);
71                 KEEP(*(.head.text.virt_vectors));
72                 *(.head.text.virt_trampolines);
73 # if defined(CONFIG_PPC_PSERIES) || defined(CONFIG_PPC_POWERNV)
74                 KEEP(*(.head.data.fwnmi_page));
75 # endif
76 #endif
77 #else /* !CONFIG_PPC64 */
78                 HEAD_TEXT
79 #endif
80         } :kernel
81
82         __head_end = .;
83
84 #ifdef CONFIG_PPC64
85         /*
86          * BLOCK(0) overrides the default output section alignment because
87          * this needs to start right after .head.text in order for fixed
88          * section placement to work.
89          */
90         .text BLOCK(0) : AT(ADDR(.text) - LOAD_OFFSET) {
91 #ifdef CONFIG_LD_HEAD_STUB_CATCH
92                 KEEP(*(.linker_stub_catch));
93                 . = . ;
94 #endif
95
96 #else
97         .text : AT(ADDR(.text) - LOAD_OFFSET) {
98                 ALIGN_FUNCTION();
99 #endif
100                 /* careful! __ftr_alt_* sections need to be close to .text */
101                 *(.text.hot TEXT_MAIN .text.fixup .text.unlikely .fixup __ftr_alt_* .ref.text);
102                 SCHED_TEXT
103                 CPUIDLE_TEXT
104                 LOCK_TEXT
105                 KPROBES_TEXT
106                 IRQENTRY_TEXT
107                 SOFTIRQENTRY_TEXT
108                 /*
109                  * -Os builds call FP save/restore functions. The powerpc64
110                  * linker generates those on demand in the .sfpr section.
111                  * .sfpr gets placed at the beginning of a group of input
112                  * sections, which can break start-of-text offset if it is
113                  * included with the main text sections, so put it by itself.
114                  */
115                 *(.sfpr);
116                 MEM_KEEP(init.text)
117                 MEM_KEEP(exit.text)
118
119 #ifdef CONFIG_PPC32
120                 *(.got1)
121                 __got2_start = .;
122                 *(.got2)
123                 __got2_end = .;
124 #endif /* CONFIG_PPC32 */
125
126         } :kernel
127
128         . = ALIGN(PAGE_SIZE);
129         _etext = .;
130         PROVIDE32 (etext = .);
131
132         /* Read-only data */
133         RO_DATA(PAGE_SIZE)
134
135 #ifdef CONFIG_PPC64
136         . = ALIGN(8);
137         __rfi_flush_fixup : AT(ADDR(__rfi_flush_fixup) - LOAD_OFFSET) {
138                 __start___rfi_flush_fixup = .;
139                 *(__rfi_flush_fixup)
140                 __stop___rfi_flush_fixup = .;
141         }
142 #endif
143
144         EXCEPTION_TABLE(0)
145
146         NOTES :kernel :notes
147
148         /* The dummy segment contents for the bug workaround mentioned above
149            near PHDRS.  */
150         .dummy : AT(ADDR(.dummy) - LOAD_OFFSET) {
151                 LONG(0)
152                 LONG(0)
153                 LONG(0)
154         } :kernel :dummy
155
156 /*
157  * Init sections discarded at runtime
158  */
159         . = ALIGN(STRICT_ALIGN_SIZE);
160         __init_begin = .;
161         INIT_TEXT_SECTION(PAGE_SIZE) :kernel
162
163         /* .exit.text is discarded at runtime, not link time,
164          * to deal with references from __bug_table
165          */
166         .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) {
167                 EXIT_TEXT
168         }
169
170         .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) {
171                 INIT_DATA
172                 __vtop_table_begin = .;
173                 KEEP(*(.vtop_fixup));
174                 __vtop_table_end = .;
175                 __ptov_table_begin = .;
176                 KEEP(*(.ptov_fixup));
177                 __ptov_table_end = .;
178         }
179
180         .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) {
181                 INIT_SETUP(16)
182         }
183
184         .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET) {
185                 INIT_CALLS
186         }
187
188         .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) {
189                 CON_INITCALL
190         }
191
192         SECURITY_INIT
193
194         . = ALIGN(8);
195         __ftr_fixup : AT(ADDR(__ftr_fixup) - LOAD_OFFSET) {
196                 __start___ftr_fixup = .;
197                 KEEP(*(__ftr_fixup))
198                 __stop___ftr_fixup = .;
199         }
200         . = ALIGN(8);
201         __mmu_ftr_fixup : AT(ADDR(__mmu_ftr_fixup) - LOAD_OFFSET) {
202                 __start___mmu_ftr_fixup = .;
203                 KEEP(*(__mmu_ftr_fixup))
204                 __stop___mmu_ftr_fixup = .;
205         }
206         . = ALIGN(8);
207         __lwsync_fixup : AT(ADDR(__lwsync_fixup) - LOAD_OFFSET) {
208                 __start___lwsync_fixup = .;
209                 KEEP(*(__lwsync_fixup))
210                 __stop___lwsync_fixup = .;
211         }
212 #ifdef CONFIG_PPC64
213         . = ALIGN(8);
214         __fw_ftr_fixup : AT(ADDR(__fw_ftr_fixup) - LOAD_OFFSET) {
215                 __start___fw_ftr_fixup = .;
216                 KEEP(*(__fw_ftr_fixup))
217                 __stop___fw_ftr_fixup = .;
218         }
219 #endif
220         .init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) {
221                 INIT_RAM_FS
222         }
223
224         PERCPU_SECTION(L1_CACHE_BYTES)
225
226         . = ALIGN(8);
227         .machine.desc : AT(ADDR(.machine.desc) - LOAD_OFFSET) {
228                 __machine_desc_start = . ;
229                 KEEP(*(.machine.desc))
230                 __machine_desc_end = . ;
231         }
232 #ifdef CONFIG_RELOCATABLE
233         . = ALIGN(8);
234         .dynsym : AT(ADDR(.dynsym) - LOAD_OFFSET)
235         {
236 #ifdef CONFIG_PPC32
237                 __dynamic_symtab = .;
238 #endif
239                 *(.dynsym)
240         }
241         .dynstr : AT(ADDR(.dynstr) - LOAD_OFFSET) { *(.dynstr) }
242         .dynamic : AT(ADDR(.dynamic) - LOAD_OFFSET)
243         {
244                 __dynamic_start = .;
245                 *(.dynamic)
246         }
247         .hash : AT(ADDR(.hash) - LOAD_OFFSET) { *(.hash) }
248         .interp : AT(ADDR(.interp) - LOAD_OFFSET) { *(.interp) }
249         .rela.dyn : AT(ADDR(.rela.dyn) - LOAD_OFFSET)
250         {
251                 __rela_dyn_start = .;
252                 *(.rela*)
253         }
254 #endif
255         /* .exit.data is discarded at runtime, not link time,
256          * to deal with references from .exit.text
257          */
258         .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) {
259                 EXIT_DATA
260         }
261
262         /* freed after init ends here */
263         . = ALIGN(PAGE_SIZE);
264         __init_end = .;
265
266 /*
267  * And now the various read/write data
268  */
269
270         . = ALIGN(PAGE_SIZE);
271         _sdata = .;
272
273 #ifdef CONFIG_PPC32
274         .data : AT(ADDR(.data) - LOAD_OFFSET) {
275                 DATA_DATA
276                 *(.data.rel*)
277                 *(SDATA_MAIN)
278                 *(.sdata2)
279                 *(.got.plt) *(.got)
280                 *(.plt)
281         }
282 #else
283         .data : AT(ADDR(.data) - LOAD_OFFSET) {
284                 DATA_DATA
285                 *(.data.rel*)
286                 *(.toc1)
287                 *(.branch_lt)
288         }
289
290         .opd : AT(ADDR(.opd) - LOAD_OFFSET) {
291                 __start_opd = .;
292                 KEEP(*(.opd))
293                 __end_opd = .;
294         }
295
296         . = ALIGN(256);
297         .got : AT(ADDR(.got) - LOAD_OFFSET) {
298                 __toc_start = .;
299 #ifndef CONFIG_RELOCATABLE
300                 __prom_init_toc_start = .;
301                 arch/powerpc/kernel/prom_init.o*(.toc .got)
302                 __prom_init_toc_end = .;
303 #endif
304                 *(.got)
305                 *(.toc)
306         }
307 #endif
308
309         /* The initial task and kernel stack */
310         INIT_TASK_DATA_SECTION(THREAD_SIZE)
311
312         .data..page_aligned : AT(ADDR(.data..page_aligned) - LOAD_OFFSET) {
313                 PAGE_ALIGNED_DATA(PAGE_SIZE)
314         }
315
316         .data..cacheline_aligned : AT(ADDR(.data..cacheline_aligned) - LOAD_OFFSET) {
317                 CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES)
318         }
319
320         .data..read_mostly : AT(ADDR(.data..read_mostly) - LOAD_OFFSET) {
321                 READ_MOSTLY_DATA(L1_CACHE_BYTES)
322         }
323
324         . = ALIGN(PAGE_SIZE);
325         .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) {
326                 NOSAVE_DATA
327         }
328
329         BUG_TABLE
330
331         . = ALIGN(PAGE_SIZE);
332         _edata  =  .;
333         PROVIDE32 (edata = .);
334
335 /*
336  * And finally the bss
337  */
338
339         BSS_SECTION(0, 0, 0)
340
341         . = ALIGN(PAGE_SIZE);
342         _end = . ;
343         PROVIDE32 (end = .);
344
345         STABS_DEBUG
346
347         DWARF_DEBUG
348
349         DISCARDS
350         /DISCARD/ : {
351                 *(*.EMB.apuinfo)
352                 *(.glink .iplt .plt .rela* .comment)
353                 *(.gnu.version*)
354                 *(.gnu.attributes)
355                 *(.eh_frame)
356         }
357 }