Merge branch 'locking-core-for-linus' of git://git.kernel.org/pub/scm/linux/kernel...
[muen/linux.git] / include / asm-generic / vmlinux.lds.h
1 /*
2  * Helper macros to support writing architecture specific
3  * linker scripts.
4  *
5  * A minimal linker scripts has following content:
6  * [This is a sample, architectures may have special requiriements]
7  *
8  * OUTPUT_FORMAT(...)
9  * OUTPUT_ARCH(...)
10  * ENTRY(...)
11  * SECTIONS
12  * {
13  *      . = START;
14  *      __init_begin = .;
15  *      HEAD_TEXT_SECTION
16  *      INIT_TEXT_SECTION(PAGE_SIZE)
17  *      INIT_DATA_SECTION(...)
18  *      PERCPU_SECTION(CACHELINE_SIZE)
19  *      __init_end = .;
20  *
21  *      _stext = .;
22  *      TEXT_SECTION = 0
23  *      _etext = .;
24  *
25  *      _sdata = .;
26  *      RO_DATA_SECTION(PAGE_SIZE)
27  *      RW_DATA_SECTION(...)
28  *      _edata = .;
29  *
30  *      EXCEPTION_TABLE(...)
31  *      NOTES
32  *
33  *      BSS_SECTION(0, 0, 0)
34  *      _end = .;
35  *
36  *      STABS_DEBUG
37  *      DWARF_DEBUG
38  *
39  *      DISCARDS                // must be the last
40  * }
41  *
42  * [__init_begin, __init_end] is the init section that may be freed after init
43  *      // __init_begin and __init_end should be page aligned, so that we can
44  *      // free the whole .init memory
45  * [_stext, _etext] is the text section
46  * [_sdata, _edata] is the data section
47  *
48  * Some of the included output section have their own set of constants.
49  * Examples are: [__initramfs_start, __initramfs_end] for initramfs and
50  *               [__nosave_begin, __nosave_end] for the nosave data
51  */
52
53 #ifndef LOAD_OFFSET
54 #define LOAD_OFFSET 0
55 #endif
56
57 /* Align . to a 8 byte boundary equals to maximum function alignment. */
58 #define ALIGN_FUNCTION()  . = ALIGN(8)
59
60 /*
61  * LD_DEAD_CODE_DATA_ELIMINATION option enables -fdata-sections, which
62  * generates .data.identifier sections, which need to be pulled in with
63  * .data. We don't want to pull in .data..other sections, which Linux
64  * has defined. Same for text and bss.
65  *
66  * RODATA_MAIN is not used because existing code already defines .rodata.x
67  * sections to be brought in with rodata.
68  */
69 #ifdef CONFIG_LD_DEAD_CODE_DATA_ELIMINATION
70 #define TEXT_MAIN .text .text.[0-9a-zA-Z_]*
71 #define DATA_MAIN .data .data.[0-9a-zA-Z_]* .data..LPBX*
72 #define SDATA_MAIN .sdata .sdata.[0-9a-zA-Z_]*
73 #define RODATA_MAIN .rodata .rodata.[0-9a-zA-Z_]*
74 #define BSS_MAIN .bss .bss.[0-9a-zA-Z_]*
75 #define SBSS_MAIN .sbss .sbss.[0-9a-zA-Z_]*
76 #else
77 #define TEXT_MAIN .text
78 #define DATA_MAIN .data
79 #define SDATA_MAIN .sdata
80 #define RODATA_MAIN .rodata
81 #define BSS_MAIN .bss
82 #define SBSS_MAIN .sbss
83 #endif
84
85 /*
86  * Align to a 32 byte boundary equal to the
87  * alignment gcc 4.5 uses for a struct
88  */
89 #define STRUCT_ALIGNMENT 32
90 #define STRUCT_ALIGN() . = ALIGN(STRUCT_ALIGNMENT)
91
92 /* The actual configuration determine if the init/exit sections
93  * are handled as text/data or they can be discarded (which
94  * often happens at runtime)
95  */
96 #ifdef CONFIG_HOTPLUG_CPU
97 #define CPU_KEEP(sec)    *(.cpu##sec)
98 #define CPU_DISCARD(sec)
99 #else
100 #define CPU_KEEP(sec)
101 #define CPU_DISCARD(sec) *(.cpu##sec)
102 #endif
103
104 #if defined(CONFIG_MEMORY_HOTPLUG)
105 #define MEM_KEEP(sec)    *(.mem##sec)
106 #define MEM_DISCARD(sec)
107 #else
108 #define MEM_KEEP(sec)
109 #define MEM_DISCARD(sec) *(.mem##sec)
110 #endif
111
112 #ifdef CONFIG_FTRACE_MCOUNT_RECORD
113 #define MCOUNT_REC()    . = ALIGN(8);                           \
114                         __start_mcount_loc = .;                 \
115                         KEEP(*(__mcount_loc))                   \
116                         __stop_mcount_loc = .;
117 #else
118 #define MCOUNT_REC()
119 #endif
120
121 #ifdef CONFIG_TRACE_BRANCH_PROFILING
122 #define LIKELY_PROFILE()        __start_annotated_branch_profile = .;   \
123                                 KEEP(*(_ftrace_annotated_branch))       \
124                                 __stop_annotated_branch_profile = .;
125 #else
126 #define LIKELY_PROFILE()
127 #endif
128
129 #ifdef CONFIG_PROFILE_ALL_BRANCHES
130 #define BRANCH_PROFILE()        __start_branch_profile = .;             \
131                                 KEEP(*(_ftrace_branch))                 \
132                                 __stop_branch_profile = .;
133 #else
134 #define BRANCH_PROFILE()
135 #endif
136
137 #ifdef CONFIG_KPROBES
138 #define KPROBE_BLACKLIST()      . = ALIGN(8);                                 \
139                                 __start_kprobe_blacklist = .;                 \
140                                 KEEP(*(_kprobe_blacklist))                    \
141                                 __stop_kprobe_blacklist = .;
142 #else
143 #define KPROBE_BLACKLIST()
144 #endif
145
146 #ifdef CONFIG_FUNCTION_ERROR_INJECTION
147 #define ERROR_INJECT_WHITELIST()        STRUCT_ALIGN();                       \
148                         __start_error_injection_whitelist = .;                \
149                         KEEP(*(_error_injection_whitelist))                   \
150                         __stop_error_injection_whitelist = .;
151 #else
152 #define ERROR_INJECT_WHITELIST()
153 #endif
154
155 #ifdef CONFIG_EVENT_TRACING
156 #define FTRACE_EVENTS() . = ALIGN(8);                                   \
157                         __start_ftrace_events = .;                      \
158                         KEEP(*(_ftrace_events))                         \
159                         __stop_ftrace_events = .;                       \
160                         __start_ftrace_eval_maps = .;                   \
161                         KEEP(*(_ftrace_eval_map))                       \
162                         __stop_ftrace_eval_maps = .;
163 #else
164 #define FTRACE_EVENTS()
165 #endif
166
167 #ifdef CONFIG_TRACING
168 #define TRACE_PRINTKS()  __start___trace_bprintk_fmt = .;      \
169                          KEEP(*(__trace_printk_fmt)) /* Trace_printk fmt' pointer */ \
170                          __stop___trace_bprintk_fmt = .;
171 #define TRACEPOINT_STR() __start___tracepoint_str = .;  \
172                          KEEP(*(__tracepoint_str)) /* Trace_printk fmt' pointer */ \
173                          __stop___tracepoint_str = .;
174 #else
175 #define TRACE_PRINTKS()
176 #define TRACEPOINT_STR()
177 #endif
178
179 #ifdef CONFIG_FTRACE_SYSCALLS
180 #define TRACE_SYSCALLS() . = ALIGN(8);                                  \
181                          __start_syscalls_metadata = .;                 \
182                          KEEP(*(__syscalls_metadata))                   \
183                          __stop_syscalls_metadata = .;
184 #else
185 #define TRACE_SYSCALLS()
186 #endif
187
188 #ifdef CONFIG_BPF_EVENTS
189 #define BPF_RAW_TP() STRUCT_ALIGN();                                    \
190                          __start__bpf_raw_tp = .;                       \
191                          KEEP(*(__bpf_raw_tp_map))                      \
192                          __stop__bpf_raw_tp = .;
193 #else
194 #define BPF_RAW_TP()
195 #endif
196
197 #ifdef CONFIG_SERIAL_EARLYCON
198 #define EARLYCON_TABLE() . = ALIGN(8);                          \
199                          __earlycon_table = .;                  \
200                          KEEP(*(__earlycon_table))              \
201                          __earlycon_table_end = .;
202 #else
203 #define EARLYCON_TABLE()
204 #endif
205
206 #define ___OF_TABLE(cfg, name)  _OF_TABLE_##cfg(name)
207 #define __OF_TABLE(cfg, name)   ___OF_TABLE(cfg, name)
208 #define OF_TABLE(cfg, name)     __OF_TABLE(IS_ENABLED(cfg), name)
209 #define _OF_TABLE_0(name)
210 #define _OF_TABLE_1(name)                                               \
211         . = ALIGN(8);                                                   \
212         __##name##_of_table = .;                                        \
213         KEEP(*(__##name##_of_table))                                    \
214         KEEP(*(__##name##_of_table_end))
215
216 #define TIMER_OF_TABLES()       OF_TABLE(CONFIG_TIMER_OF, timer)
217 #define IRQCHIP_OF_MATCH_TABLE() OF_TABLE(CONFIG_IRQCHIP, irqchip)
218 #define CLK_OF_TABLES()         OF_TABLE(CONFIG_COMMON_CLK, clk)
219 #define RESERVEDMEM_OF_TABLES() OF_TABLE(CONFIG_OF_RESERVED_MEM, reservedmem)
220 #define CPU_METHOD_OF_TABLES()  OF_TABLE(CONFIG_SMP, cpu_method)
221 #define CPUIDLE_METHOD_OF_TABLES() OF_TABLE(CONFIG_CPU_IDLE, cpuidle_method)
222
223 #ifdef CONFIG_ACPI
224 #define ACPI_PROBE_TABLE(name)                                          \
225         . = ALIGN(8);                                                   \
226         __##name##_acpi_probe_table = .;                                \
227         KEEP(*(__##name##_acpi_probe_table))                            \
228         __##name##_acpi_probe_table_end = .;
229 #else
230 #define ACPI_PROBE_TABLE(name)
231 #endif
232
233 #define KERNEL_DTB()                                                    \
234         STRUCT_ALIGN();                                                 \
235         __dtb_start = .;                                                \
236         KEEP(*(.dtb.init.rodata))                                       \
237         __dtb_end = .;
238
239 /*
240  * .data section
241  */
242 #define DATA_DATA                                                       \
243         *(.xiptext)                                                     \
244         *(DATA_MAIN)                                                    \
245         *(.ref.data)                                                    \
246         *(.data..shared_aligned) /* percpu related */                   \
247         MEM_KEEP(init.data*)                                            \
248         MEM_KEEP(exit.data*)                                            \
249         *(.data.unlikely)                                               \
250         __start_once = .;                                               \
251         *(.data.once)                                                   \
252         __end_once = .;                                                 \
253         STRUCT_ALIGN();                                                 \
254         *(__tracepoints)                                                \
255         /* implement dynamic printk debug */                            \
256         . = ALIGN(8);                                                   \
257         __start___verbose = .;                                          \
258         KEEP(*(__verbose))                                              \
259         __stop___verbose = .;                                           \
260         LIKELY_PROFILE()                                                \
261         BRANCH_PROFILE()                                                \
262         TRACE_PRINTKS()                                                 \
263         BPF_RAW_TP()                                                    \
264         TRACEPOINT_STR()
265
266 /*
267  * Data section helpers
268  */
269 #define NOSAVE_DATA                                                     \
270         . = ALIGN(PAGE_SIZE);                                           \
271         __nosave_begin = .;                                             \
272         *(.data..nosave)                                                \
273         . = ALIGN(PAGE_SIZE);                                           \
274         __nosave_end = .;
275
276 #define PAGE_ALIGNED_DATA(page_align)                                   \
277         . = ALIGN(page_align);                                          \
278         *(.data..page_aligned)
279
280 #define READ_MOSTLY_DATA(align)                                         \
281         . = ALIGN(align);                                               \
282         *(.data..read_mostly)                                           \
283         . = ALIGN(align);
284
285 #define CACHELINE_ALIGNED_DATA(align)                                   \
286         . = ALIGN(align);                                               \
287         *(.data..cacheline_aligned)
288
289 #define INIT_TASK_DATA(align)                                           \
290         . = ALIGN(align);                                               \
291         __start_init_task = .;                                          \
292         init_thread_union = .;                                          \
293         init_stack = .;                                                 \
294         KEEP(*(.data..init_task))                                       \
295         KEEP(*(.data..init_thread_info))                                \
296         . = __start_init_task + THREAD_SIZE;                            \
297         __end_init_task = .;
298
299 #define JUMP_TABLE_DATA                                                 \
300         . = ALIGN(8);                                                   \
301         __start___jump_table = .;                                       \
302         KEEP(*(__jump_table))                                           \
303         __stop___jump_table = .;
304
305 /*
306  * Allow architectures to handle ro_after_init data on their
307  * own by defining an empty RO_AFTER_INIT_DATA.
308  */
309 #ifndef RO_AFTER_INIT_DATA
310 #define RO_AFTER_INIT_DATA                                              \
311         __start_ro_after_init = .;                                      \
312         *(.data..ro_after_init)                                         \
313         JUMP_TABLE_DATA                                                 \
314         __end_ro_after_init = .;
315 #endif
316
317 /*
318  * Read only Data
319  */
320 #define RO_DATA_SECTION(align)                                          \
321         . = ALIGN((align));                                             \
322         .rodata           : AT(ADDR(.rodata) - LOAD_OFFSET) {           \
323                 __start_rodata = .;                                     \
324                 *(.rodata) *(.rodata.*)                                 \
325                 RO_AFTER_INIT_DATA      /* Read only after init */      \
326                 KEEP(*(__vermagic))     /* Kernel version magic */      \
327                 . = ALIGN(8);                                           \
328                 __start___tracepoints_ptrs = .;                         \
329                 KEEP(*(__tracepoints_ptrs)) /* Tracepoints: pointer array */ \
330                 __stop___tracepoints_ptrs = .;                          \
331                 *(__tracepoints_strings)/* Tracepoints: strings */      \
332         }                                                               \
333                                                                         \
334         .rodata1          : AT(ADDR(.rodata1) - LOAD_OFFSET) {          \
335                 *(.rodata1)                                             \
336         }                                                               \
337                                                                         \
338         /* PCI quirks */                                                \
339         .pci_fixup        : AT(ADDR(.pci_fixup) - LOAD_OFFSET) {        \
340                 __start_pci_fixups_early = .;                           \
341                 KEEP(*(.pci_fixup_early))                               \
342                 __end_pci_fixups_early = .;                             \
343                 __start_pci_fixups_header = .;                          \
344                 KEEP(*(.pci_fixup_header))                              \
345                 __end_pci_fixups_header = .;                            \
346                 __start_pci_fixups_final = .;                           \
347                 KEEP(*(.pci_fixup_final))                               \
348                 __end_pci_fixups_final = .;                             \
349                 __start_pci_fixups_enable = .;                          \
350                 KEEP(*(.pci_fixup_enable))                              \
351                 __end_pci_fixups_enable = .;                            \
352                 __start_pci_fixups_resume = .;                          \
353                 KEEP(*(.pci_fixup_resume))                              \
354                 __end_pci_fixups_resume = .;                            \
355                 __start_pci_fixups_resume_early = .;                    \
356                 KEEP(*(.pci_fixup_resume_early))                        \
357                 __end_pci_fixups_resume_early = .;                      \
358                 __start_pci_fixups_suspend = .;                         \
359                 KEEP(*(.pci_fixup_suspend))                             \
360                 __end_pci_fixups_suspend = .;                           \
361                 __start_pci_fixups_suspend_late = .;                    \
362                 KEEP(*(.pci_fixup_suspend_late))                        \
363                 __end_pci_fixups_suspend_late = .;                      \
364         }                                                               \
365                                                                         \
366         /* Built-in firmware blobs */                                   \
367         .builtin_fw        : AT(ADDR(.builtin_fw) - LOAD_OFFSET) {      \
368                 __start_builtin_fw = .;                                 \
369                 KEEP(*(.builtin_fw))                                    \
370                 __end_builtin_fw = .;                                   \
371         }                                                               \
372                                                                         \
373         TRACEDATA                                                       \
374                                                                         \
375         /* Kernel symbol table: Normal symbols */                       \
376         __ksymtab         : AT(ADDR(__ksymtab) - LOAD_OFFSET) {         \
377                 __start___ksymtab = .;                                  \
378                 KEEP(*(SORT(___ksymtab+*)))                             \
379                 __stop___ksymtab = .;                                   \
380         }                                                               \
381                                                                         \
382         /* Kernel symbol table: GPL-only symbols */                     \
383         __ksymtab_gpl     : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) {     \
384                 __start___ksymtab_gpl = .;                              \
385                 KEEP(*(SORT(___ksymtab_gpl+*)))                         \
386                 __stop___ksymtab_gpl = .;                               \
387         }                                                               \
388                                                                         \
389         /* Kernel symbol table: Normal unused symbols */                \
390         __ksymtab_unused  : AT(ADDR(__ksymtab_unused) - LOAD_OFFSET) {  \
391                 __start___ksymtab_unused = .;                           \
392                 KEEP(*(SORT(___ksymtab_unused+*)))                      \
393                 __stop___ksymtab_unused = .;                            \
394         }                                                               \
395                                                                         \
396         /* Kernel symbol table: GPL-only unused symbols */              \
397         __ksymtab_unused_gpl : AT(ADDR(__ksymtab_unused_gpl) - LOAD_OFFSET) { \
398                 __start___ksymtab_unused_gpl = .;                       \
399                 KEEP(*(SORT(___ksymtab_unused_gpl+*)))                  \
400                 __stop___ksymtab_unused_gpl = .;                        \
401         }                                                               \
402                                                                         \
403         /* Kernel symbol table: GPL-future-only symbols */              \
404         __ksymtab_gpl_future : AT(ADDR(__ksymtab_gpl_future) - LOAD_OFFSET) { \
405                 __start___ksymtab_gpl_future = .;                       \
406                 KEEP(*(SORT(___ksymtab_gpl_future+*)))                  \
407                 __stop___ksymtab_gpl_future = .;                        \
408         }                                                               \
409                                                                         \
410         /* Kernel symbol table: Normal symbols */                       \
411         __kcrctab         : AT(ADDR(__kcrctab) - LOAD_OFFSET) {         \
412                 __start___kcrctab = .;                                  \
413                 KEEP(*(SORT(___kcrctab+*)))                             \
414                 __stop___kcrctab = .;                                   \
415         }                                                               \
416                                                                         \
417         /* Kernel symbol table: GPL-only symbols */                     \
418         __kcrctab_gpl     : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) {     \
419                 __start___kcrctab_gpl = .;                              \
420                 KEEP(*(SORT(___kcrctab_gpl+*)))                         \
421                 __stop___kcrctab_gpl = .;                               \
422         }                                                               \
423                                                                         \
424         /* Kernel symbol table: Normal unused symbols */                \
425         __kcrctab_unused  : AT(ADDR(__kcrctab_unused) - LOAD_OFFSET) {  \
426                 __start___kcrctab_unused = .;                           \
427                 KEEP(*(SORT(___kcrctab_unused+*)))                      \
428                 __stop___kcrctab_unused = .;                            \
429         }                                                               \
430                                                                         \
431         /* Kernel symbol table: GPL-only unused symbols */              \
432         __kcrctab_unused_gpl : AT(ADDR(__kcrctab_unused_gpl) - LOAD_OFFSET) { \
433                 __start___kcrctab_unused_gpl = .;                       \
434                 KEEP(*(SORT(___kcrctab_unused_gpl+*)))                  \
435                 __stop___kcrctab_unused_gpl = .;                        \
436         }                                                               \
437                                                                         \
438         /* Kernel symbol table: GPL-future-only symbols */              \
439         __kcrctab_gpl_future : AT(ADDR(__kcrctab_gpl_future) - LOAD_OFFSET) { \
440                 __start___kcrctab_gpl_future = .;                       \
441                 KEEP(*(SORT(___kcrctab_gpl_future+*)))                  \
442                 __stop___kcrctab_gpl_future = .;                        \
443         }                                                               \
444                                                                         \
445         /* Kernel symbol table: strings */                              \
446         __ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) { \
447                 *(__ksymtab_strings)                                    \
448         }                                                               \
449                                                                         \
450         /* __*init sections */                                          \
451         __init_rodata : AT(ADDR(__init_rodata) - LOAD_OFFSET) {         \
452                 *(.ref.rodata)                                          \
453                 MEM_KEEP(init.rodata)                                   \
454                 MEM_KEEP(exit.rodata)                                   \
455         }                                                               \
456                                                                         \
457         /* Built-in module parameters. */                               \
458         __param : AT(ADDR(__param) - LOAD_OFFSET) {                     \
459                 __start___param = .;                                    \
460                 KEEP(*(__param))                                        \
461                 __stop___param = .;                                     \
462         }                                                               \
463                                                                         \
464         /* Built-in module versions. */                                 \
465         __modver : AT(ADDR(__modver) - LOAD_OFFSET) {                   \
466                 __start___modver = .;                                   \
467                 KEEP(*(__modver))                                       \
468                 __stop___modver = .;                                    \
469                 . = ALIGN((align));                                     \
470                 __end_rodata = .;                                       \
471         }                                                               \
472         . = ALIGN((align));
473
474 /* RODATA & RO_DATA provided for backward compatibility.
475  * All archs are supposed to use RO_DATA() */
476 #define RODATA          RO_DATA_SECTION(4096)
477 #define RO_DATA(align)  RO_DATA_SECTION(align)
478
479 #define SECURITY_INIT                                                   \
480         .security_initcall.init : AT(ADDR(.security_initcall.init) - LOAD_OFFSET) { \
481                 __security_initcall_start = .;                          \
482                 KEEP(*(.security_initcall.init))                        \
483                 __security_initcall_end = .;                            \
484         }
485
486 /*
487  * .text section. Map to function alignment to avoid address changes
488  * during second ld run in second ld pass when generating System.map
489  *
490  * TEXT_MAIN here will match .text.fixup and .text.unlikely if dead
491  * code elimination is enabled, so these sections should be converted
492  * to use ".." first.
493  */
494 #define TEXT_TEXT                                                       \
495                 ALIGN_FUNCTION();                                       \
496                 *(.text.hot TEXT_MAIN .text.fixup .text.unlikely)       \
497                 *(.text..refcount)                                      \
498                 *(.ref.text)                                            \
499         MEM_KEEP(init.text*)                                            \
500         MEM_KEEP(exit.text*)                                            \
501
502
503 /* sched.text is aling to function alignment to secure we have same
504  * address even at second ld pass when generating System.map */
505 #define SCHED_TEXT                                                      \
506                 ALIGN_FUNCTION();                                       \
507                 __sched_text_start = .;                                 \
508                 *(.sched.text)                                          \
509                 __sched_text_end = .;
510
511 /* spinlock.text is aling to function alignment to secure we have same
512  * address even at second ld pass when generating System.map */
513 #define LOCK_TEXT                                                       \
514                 ALIGN_FUNCTION();                                       \
515                 __lock_text_start = .;                                  \
516                 *(.spinlock.text)                                       \
517                 __lock_text_end = .;
518
519 #define CPUIDLE_TEXT                                                    \
520                 ALIGN_FUNCTION();                                       \
521                 __cpuidle_text_start = .;                               \
522                 *(.cpuidle.text)                                        \
523                 __cpuidle_text_end = .;
524
525 #define KPROBES_TEXT                                                    \
526                 ALIGN_FUNCTION();                                       \
527                 __kprobes_text_start = .;                               \
528                 *(.kprobes.text)                                        \
529                 __kprobes_text_end = .;
530
531 #define ENTRY_TEXT                                                      \
532                 ALIGN_FUNCTION();                                       \
533                 __entry_text_start = .;                                 \
534                 *(.entry.text)                                          \
535                 __entry_text_end = .;
536
537 #define IRQENTRY_TEXT                                                   \
538                 ALIGN_FUNCTION();                                       \
539                 __irqentry_text_start = .;                              \
540                 *(.irqentry.text)                                       \
541                 __irqentry_text_end = .;
542
543 #define SOFTIRQENTRY_TEXT                                               \
544                 ALIGN_FUNCTION();                                       \
545                 __softirqentry_text_start = .;                          \
546                 *(.softirqentry.text)                                   \
547                 __softirqentry_text_end = .;
548
549 /* Section used for early init (in .S files) */
550 #define HEAD_TEXT  KEEP(*(.head.text))
551
552 #define HEAD_TEXT_SECTION                                                       \
553         .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) {               \
554                 HEAD_TEXT                                               \
555         }
556
557 /*
558  * Exception table
559  */
560 #define EXCEPTION_TABLE(align)                                          \
561         . = ALIGN(align);                                               \
562         __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) {               \
563                 __start___ex_table = .;                                 \
564                 KEEP(*(__ex_table))                                     \
565                 __stop___ex_table = .;                                  \
566         }
567
568 /*
569  * Init task
570  */
571 #define INIT_TASK_DATA_SECTION(align)                                   \
572         . = ALIGN(align);                                               \
573         .data..init_task :  AT(ADDR(.data..init_task) - LOAD_OFFSET) {  \
574                 INIT_TASK_DATA(align)                                   \
575         }
576
577 #ifdef CONFIG_CONSTRUCTORS
578 #define KERNEL_CTORS()  . = ALIGN(8);                      \
579                         __ctors_start = .;                 \
580                         KEEP(*(.ctors))                    \
581                         KEEP(*(SORT(.init_array.*)))       \
582                         KEEP(*(.init_array))               \
583                         __ctors_end = .;
584 #else
585 #define KERNEL_CTORS()
586 #endif
587
588 /* init and exit section handling */
589 #define INIT_DATA                                                       \
590         KEEP(*(SORT(___kentry+*)))                                      \
591         *(.init.data init.data.*)                                       \
592         MEM_DISCARD(init.data*)                                         \
593         KERNEL_CTORS()                                                  \
594         MCOUNT_REC()                                                    \
595         *(.init.rodata .init.rodata.*)                                  \
596         FTRACE_EVENTS()                                                 \
597         TRACE_SYSCALLS()                                                \
598         KPROBE_BLACKLIST()                                              \
599         ERROR_INJECT_WHITELIST()                                        \
600         MEM_DISCARD(init.rodata)                                        \
601         CLK_OF_TABLES()                                                 \
602         RESERVEDMEM_OF_TABLES()                                         \
603         TIMER_OF_TABLES()                                               \
604         CPU_METHOD_OF_TABLES()                                          \
605         CPUIDLE_METHOD_OF_TABLES()                                      \
606         KERNEL_DTB()                                                    \
607         IRQCHIP_OF_MATCH_TABLE()                                        \
608         ACPI_PROBE_TABLE(irqchip)                                       \
609         ACPI_PROBE_TABLE(timer)                                         \
610         EARLYCON_TABLE()
611
612 #define INIT_TEXT                                                       \
613         *(.init.text .init.text.*)                                      \
614         *(.text.startup)                                                \
615         MEM_DISCARD(init.text*)
616
617 #define EXIT_DATA                                                       \
618         *(.exit.data .exit.data.*)                                      \
619         *(.fini_array .fini_array.*)                                    \
620         *(.dtors .dtors.*)                                              \
621         MEM_DISCARD(exit.data*)                                         \
622         MEM_DISCARD(exit.rodata*)
623
624 #define EXIT_TEXT                                                       \
625         *(.exit.text)                                                   \
626         *(.text.exit)                                                   \
627         MEM_DISCARD(exit.text)
628
629 #define EXIT_CALL                                                       \
630         *(.exitcall.exit)
631
632 /*
633  * bss (Block Started by Symbol) - uninitialized data
634  * zeroed during startup
635  */
636 #define SBSS(sbss_align)                                                \
637         . = ALIGN(sbss_align);                                          \
638         .sbss : AT(ADDR(.sbss) - LOAD_OFFSET) {                         \
639                 *(.dynsbss)                                             \
640                 *(SBSS_MAIN)                                            \
641                 *(.scommon)                                             \
642         }
643
644 /*
645  * Allow archectures to redefine BSS_FIRST_SECTIONS to add extra
646  * sections to the front of bss.
647  */
648 #ifndef BSS_FIRST_SECTIONS
649 #define BSS_FIRST_SECTIONS
650 #endif
651
652 #define BSS(bss_align)                                                  \
653         . = ALIGN(bss_align);                                           \
654         .bss : AT(ADDR(.bss) - LOAD_OFFSET) {                           \
655                 BSS_FIRST_SECTIONS                                      \
656                 *(.bss..page_aligned)                                   \
657                 *(.dynbss)                                              \
658                 *(BSS_MAIN)                                             \
659                 *(COMMON)                                               \
660         }
661
662 /*
663  * DWARF debug sections.
664  * Symbols in the DWARF debugging sections are relative to
665  * the beginning of the section so we begin them at 0.
666  */
667 #define DWARF_DEBUG                                                     \
668                 /* DWARF 1 */                                           \
669                 .debug          0 : { *(.debug) }                       \
670                 .line           0 : { *(.line) }                        \
671                 /* GNU DWARF 1 extensions */                            \
672                 .debug_srcinfo  0 : { *(.debug_srcinfo) }               \
673                 .debug_sfnames  0 : { *(.debug_sfnames) }               \
674                 /* DWARF 1.1 and DWARF 2 */                             \
675                 .debug_aranges  0 : { *(.debug_aranges) }               \
676                 .debug_pubnames 0 : { *(.debug_pubnames) }              \
677                 /* DWARF 2 */                                           \
678                 .debug_info     0 : { *(.debug_info                     \
679                                 .gnu.linkonce.wi.*) }                   \
680                 .debug_abbrev   0 : { *(.debug_abbrev) }                \
681                 .debug_line     0 : { *(.debug_line) }                  \
682                 .debug_frame    0 : { *(.debug_frame) }                 \
683                 .debug_str      0 : { *(.debug_str) }                   \
684                 .debug_loc      0 : { *(.debug_loc) }                   \
685                 .debug_macinfo  0 : { *(.debug_macinfo) }               \
686                 .debug_pubtypes 0 : { *(.debug_pubtypes) }              \
687                 /* DWARF 3 */                                           \
688                 .debug_ranges   0 : { *(.debug_ranges) }                \
689                 /* SGI/MIPS DWARF 2 extensions */                       \
690                 .debug_weaknames 0 : { *(.debug_weaknames) }            \
691                 .debug_funcnames 0 : { *(.debug_funcnames) }            \
692                 .debug_typenames 0 : { *(.debug_typenames) }            \
693                 .debug_varnames  0 : { *(.debug_varnames) }             \
694                 /* GNU DWARF 2 extensions */                            \
695                 .debug_gnu_pubnames 0 : { *(.debug_gnu_pubnames) }      \
696                 .debug_gnu_pubtypes 0 : { *(.debug_gnu_pubtypes) }      \
697                 /* DWARF 4 */                                           \
698                 .debug_types    0 : { *(.debug_types) }                 \
699                 /* DWARF 5 */                                           \
700                 .debug_macro    0 : { *(.debug_macro) }                 \
701                 .debug_addr     0 : { *(.debug_addr) }
702
703                 /* Stabs debugging sections.  */
704 #define STABS_DEBUG                                                     \
705                 .stab 0 : { *(.stab) }                                  \
706                 .stabstr 0 : { *(.stabstr) }                            \
707                 .stab.excl 0 : { *(.stab.excl) }                        \
708                 .stab.exclstr 0 : { *(.stab.exclstr) }                  \
709                 .stab.index 0 : { *(.stab.index) }                      \
710                 .stab.indexstr 0 : { *(.stab.indexstr) }                \
711                 .comment 0 : { *(.comment) }
712
713 #ifdef CONFIG_GENERIC_BUG
714 #define BUG_TABLE                                                       \
715         . = ALIGN(8);                                                   \
716         __bug_table : AT(ADDR(__bug_table) - LOAD_OFFSET) {             \
717                 __start___bug_table = .;                                \
718                 KEEP(*(__bug_table))                                    \
719                 __stop___bug_table = .;                                 \
720         }
721 #else
722 #define BUG_TABLE
723 #endif
724
725 #ifdef CONFIG_UNWINDER_ORC
726 #define ORC_UNWIND_TABLE                                                \
727         . = ALIGN(4);                                                   \
728         .orc_unwind_ip : AT(ADDR(.orc_unwind_ip) - LOAD_OFFSET) {       \
729                 __start_orc_unwind_ip = .;                              \
730                 KEEP(*(.orc_unwind_ip))                                 \
731                 __stop_orc_unwind_ip = .;                               \
732         }                                                               \
733         . = ALIGN(6);                                                   \
734         .orc_unwind : AT(ADDR(.orc_unwind) - LOAD_OFFSET) {             \
735                 __start_orc_unwind = .;                                 \
736                 KEEP(*(.orc_unwind))                                    \
737                 __stop_orc_unwind = .;                                  \
738         }                                                               \
739         . = ALIGN(4);                                                   \
740         .orc_lookup : AT(ADDR(.orc_lookup) - LOAD_OFFSET) {             \
741                 orc_lookup = .;                                         \
742                 . += (((SIZEOF(.text) + LOOKUP_BLOCK_SIZE - 1) /        \
743                         LOOKUP_BLOCK_SIZE) + 1) * 4;                    \
744                 orc_lookup_end = .;                                     \
745         }
746 #else
747 #define ORC_UNWIND_TABLE
748 #endif
749
750 #ifdef CONFIG_PM_TRACE
751 #define TRACEDATA                                                       \
752         . = ALIGN(4);                                                   \
753         .tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) {               \
754                 __tracedata_start = .;                                  \
755                 KEEP(*(.tracedata))                                     \
756                 __tracedata_end = .;                                    \
757         }
758 #else
759 #define TRACEDATA
760 #endif
761
762 #define NOTES                                                           \
763         .notes : AT(ADDR(.notes) - LOAD_OFFSET) {                       \
764                 __start_notes = .;                                      \
765                 KEEP(*(.note.*))                                        \
766                 __stop_notes = .;                                       \
767         }
768
769 #define INIT_SETUP(initsetup_align)                                     \
770                 . = ALIGN(initsetup_align);                             \
771                 __setup_start = .;                                      \
772                 KEEP(*(.init.setup))                                    \
773                 __setup_end = .;
774
775 #define INIT_CALLS_LEVEL(level)                                         \
776                 __initcall##level##_start = .;                          \
777                 KEEP(*(.initcall##level##.init))                        \
778                 KEEP(*(.initcall##level##s.init))                       \
779
780 #define INIT_CALLS                                                      \
781                 __initcall_start = .;                                   \
782                 KEEP(*(.initcallearly.init))                            \
783                 INIT_CALLS_LEVEL(0)                                     \
784                 INIT_CALLS_LEVEL(1)                                     \
785                 INIT_CALLS_LEVEL(2)                                     \
786                 INIT_CALLS_LEVEL(3)                                     \
787                 INIT_CALLS_LEVEL(4)                                     \
788                 INIT_CALLS_LEVEL(5)                                     \
789                 INIT_CALLS_LEVEL(rootfs)                                \
790                 INIT_CALLS_LEVEL(6)                                     \
791                 INIT_CALLS_LEVEL(7)                                     \
792                 __initcall_end = .;
793
794 #define CON_INITCALL                                                    \
795                 __con_initcall_start = .;                               \
796                 KEEP(*(.con_initcall.init))                             \
797                 __con_initcall_end = .;
798
799 #define SECURITY_INITCALL                                               \
800                 __security_initcall_start = .;                          \
801                 KEEP(*(.security_initcall.init))                        \
802                 __security_initcall_end = .;
803
804 #ifdef CONFIG_BLK_DEV_INITRD
805 #define INIT_RAM_FS                                                     \
806         . = ALIGN(4);                                                   \
807         __initramfs_start = .;                                          \
808         KEEP(*(.init.ramfs))                                            \
809         . = ALIGN(8);                                                   \
810         KEEP(*(.init.ramfs.info))
811 #else
812 #define INIT_RAM_FS
813 #endif
814
815 /*
816  * Memory encryption operates on a page basis. Since we need to clear
817  * the memory encryption mask for this section, it needs to be aligned
818  * on a page boundary and be a page-size multiple in length.
819  *
820  * Note: We use a separate section so that only this section gets
821  * decrypted to avoid exposing more than we wish.
822  */
823 #ifdef CONFIG_AMD_MEM_ENCRYPT
824 #define PERCPU_DECRYPTED_SECTION                                        \
825         . = ALIGN(PAGE_SIZE);                                           \
826         *(.data..percpu..decrypted)                                     \
827         . = ALIGN(PAGE_SIZE);
828 #else
829 #define PERCPU_DECRYPTED_SECTION
830 #endif
831
832
833 /*
834  * Default discarded sections.
835  *
836  * Some archs want to discard exit text/data at runtime rather than
837  * link time due to cross-section references such as alt instructions,
838  * bug table, eh_frame, etc.  DISCARDS must be the last of output
839  * section definitions so that such archs put those in earlier section
840  * definitions.
841  */
842 #define DISCARDS                                                        \
843         /DISCARD/ : {                                                   \
844         EXIT_TEXT                                                       \
845         EXIT_DATA                                                       \
846         EXIT_CALL                                                       \
847         *(.discard)                                                     \
848         *(.discard.*)                                                   \
849         }
850
851 /**
852  * PERCPU_INPUT - the percpu input sections
853  * @cacheline: cacheline size
854  *
855  * The core percpu section names and core symbols which do not rely
856  * directly upon load addresses.
857  *
858  * @cacheline is used to align subsections to avoid false cacheline
859  * sharing between subsections for different purposes.
860  */
861 #define PERCPU_INPUT(cacheline)                                         \
862         __per_cpu_start = .;                                            \
863         *(.data..percpu..first)                                         \
864         . = ALIGN(PAGE_SIZE);                                           \
865         *(.data..percpu..page_aligned)                                  \
866         . = ALIGN(cacheline);                                           \
867         *(.data..percpu..read_mostly)                                   \
868         . = ALIGN(cacheline);                                           \
869         *(.data..percpu)                                                \
870         *(.data..percpu..shared_aligned)                                \
871         PERCPU_DECRYPTED_SECTION                                        \
872         __per_cpu_end = .;
873
874 /**
875  * PERCPU_VADDR - define output section for percpu area
876  * @cacheline: cacheline size
877  * @vaddr: explicit base address (optional)
878  * @phdr: destination PHDR (optional)
879  *
880  * Macro which expands to output section for percpu area.
881  *
882  * @cacheline is used to align subsections to avoid false cacheline
883  * sharing between subsections for different purposes.
884  *
885  * If @vaddr is not blank, it specifies explicit base address and all
886  * percpu symbols will be offset from the given address.  If blank,
887  * @vaddr always equals @laddr + LOAD_OFFSET.
888  *
889  * @phdr defines the output PHDR to use if not blank.  Be warned that
890  * output PHDR is sticky.  If @phdr is specified, the next output
891  * section in the linker script will go there too.  @phdr should have
892  * a leading colon.
893  *
894  * Note that this macros defines __per_cpu_load as an absolute symbol.
895  * If there is no need to put the percpu section at a predetermined
896  * address, use PERCPU_SECTION.
897  */
898 #define PERCPU_VADDR(cacheline, vaddr, phdr)                            \
899         __per_cpu_load = .;                                             \
900         .data..percpu vaddr : AT(__per_cpu_load - LOAD_OFFSET) {        \
901                 PERCPU_INPUT(cacheline)                                 \
902         } phdr                                                          \
903         . = __per_cpu_load + SIZEOF(.data..percpu);
904
905 /**
906  * PERCPU_SECTION - define output section for percpu area, simple version
907  * @cacheline: cacheline size
908  *
909  * Align to PAGE_SIZE and outputs output section for percpu area.  This
910  * macro doesn't manipulate @vaddr or @phdr and __per_cpu_load and
911  * __per_cpu_start will be identical.
912  *
913  * This macro is equivalent to ALIGN(PAGE_SIZE); PERCPU_VADDR(@cacheline,,)
914  * except that __per_cpu_load is defined as a relative symbol against
915  * .data..percpu which is required for relocatable x86_32 configuration.
916  */
917 #define PERCPU_SECTION(cacheline)                                       \
918         . = ALIGN(PAGE_SIZE);                                           \
919         .data..percpu   : AT(ADDR(.data..percpu) - LOAD_OFFSET) {       \
920                 __per_cpu_load = .;                                     \
921                 PERCPU_INPUT(cacheline)                                 \
922         }
923
924
925 /*
926  * Definition of the high level *_SECTION macros
927  * They will fit only a subset of the architectures
928  */
929
930
931 /*
932  * Writeable data.
933  * All sections are combined in a single .data section.
934  * The sections following CONSTRUCTORS are arranged so their
935  * typical alignment matches.
936  * A cacheline is typical/always less than a PAGE_SIZE so
937  * the sections that has this restriction (or similar)
938  * is located before the ones requiring PAGE_SIZE alignment.
939  * NOSAVE_DATA starts and ends with a PAGE_SIZE alignment which
940  * matches the requirement of PAGE_ALIGNED_DATA.
941  *
942  * use 0 as page_align if page_aligned data is not used */
943 #define RW_DATA_SECTION(cacheline, pagealigned, inittask)               \
944         . = ALIGN(PAGE_SIZE);                                           \
945         .data : AT(ADDR(.data) - LOAD_OFFSET) {                         \
946                 INIT_TASK_DATA(inittask)                                \
947                 NOSAVE_DATA                                             \
948                 PAGE_ALIGNED_DATA(pagealigned)                          \
949                 CACHELINE_ALIGNED_DATA(cacheline)                       \
950                 READ_MOSTLY_DATA(cacheline)                             \
951                 DATA_DATA                                               \
952                 CONSTRUCTORS                                            \
953         }                                                               \
954         BUG_TABLE                                                       \
955
956 #define INIT_TEXT_SECTION(inittext_align)                               \
957         . = ALIGN(inittext_align);                                      \
958         .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {               \
959                 _sinittext = .;                                         \
960                 INIT_TEXT                                               \
961                 _einittext = .;                                         \
962         }
963
964 #define INIT_DATA_SECTION(initsetup_align)                              \
965         .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) {               \
966                 INIT_DATA                                               \
967                 INIT_SETUP(initsetup_align)                             \
968                 INIT_CALLS                                              \
969                 CON_INITCALL                                            \
970                 SECURITY_INITCALL                                       \
971                 INIT_RAM_FS                                             \
972         }
973
974 #define BSS_SECTION(sbss_align, bss_align, stop_align)                  \
975         . = ALIGN(sbss_align);                                          \
976         __bss_start = .;                                                \
977         SBSS(sbss_align)                                                \
978         BSS(bss_align)                                                  \
979         . = ALIGN(stop_align);                                          \
980         __bss_stop = .;